在VB中使用水晶报表的一种简易编程方法

第一步：
在VB工程中Project菜单加入"Add Crystal Report 9"，报表名使用默认即可。这时Form2（Crystal　Rerport自动添加的Form，假设名为Form2）被自动分配了如下代码：

Option Explicit
dim Report as New Cystal1

Private Sub Form_Load()

Screen.MousePointer = vbHourglass     '调用水晶报表时置鼠标为沙漏状

CRViewer91.ReportSource = Report     '该语句的赋值将在后面被修改

CRViewer91.ViewReport
Screen.MousePointer = vbDefault       '调用水晶报表完成后置鼠标为默认形状

End Sub

Private Sub Form_Resize()

CRViewer91.Top = 0
CRViewer91.Left = 0
CRViewer91.Height = ScaleHeight
CRViewer91.Width = ScaleWidth

End Sub

第二步：
点击Crystal Report设计器的"数据库字段"，选定"数据库专家..."，然后点"创建新连接"，再点"仅字段定义"，创建"数据库定义"文件，字段名和宽度和原数据库表保持一致。最后，在数据库字段中获得了相应字段，将其置于报表上，按水晶报表的要求配置。

第三步：
该步骤非常关键，添加一个Modual到工程文件中，定义全局的ADODB变量，实现数据库和水晶报表的动态连接。代码如下：

Public conn As New ADODB.Connection
Public rs As New ADODB.Recordset

第四步：
关于VB程序的ADO数据库连接注意事项，请看下面的打印按钮例程。

Private Sub Command1_Click()

    Dim connstr As String

    If conn.State = adStateOpen Then conn.Close
   
    connstr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & App.Path & "\prtest.mdb;Persist Security Info=False"    'prtest.mdb是程序当前目录的测试Access数据库
   
    conn.ConnectionString = connstr
   
    conn.Open
   
    conn.CursorLocation = adUseClient
   
    If rs.State = adStateOpen Then rs.Close
   
    rs.Open "test", conn, adOpenKeyset, adLockReadOnly
   
'    Report.Database.SetDataSource rs, 3, 1  '此行取消
   

    Form2.Show 1   '数据库连接完成后，调用Form2水晶报表工程
   
   
End Sub

需要提请大家注意的是，上面代码中的Report.Database.SetDataSource rs, 3, 1是初用水晶报表的程序员容易犯的错误，使用该语句后将造成数据库和水晶报表的连接失败。如何动态调用水晶报表呢？请看第五步。

第五步：
创建水晶报表和数据库数据源的连接，需要修改上面Form2的代码。

Option Explicit
'dim Report as New Cystal1
'上面一行取消

Private Sub Form_Load()

Dim oApp As New CRAXDRT.Application
Dim oRpt As CRAXDRT.Report
Dim reportName As String
'上面三行是新增加的

Screen.MousePointer = vbHourglass

reportName = "\rpt\Pr1.rpt"　　    '定义要引用的rpt文件

Set oRpt = oApp.OpenReport(App.Path & reportName, 1)

oRpt.Database.SetDataSource rs    '连接水晶报表和数据源
oRpt.ReadRecords

CRViewer91.ReportSource = oRpt  '启用水晶报表的预览功能

CRViewer91.ViewReport
Screen.MousePointer = vbDefault

End Sub

Private Sub Form_Resize()

CRViewer91.Top = 0
CRViewer91.Left = 0
CRViewer91.Height = ScaleHeight
CRViewer91.Width = ScaleWidth

End Sub

Private Sub Form_Unload(Cancel As Integer)
   
    'Set Report = Nothing
   
    Set rs = Nothing
   
    Set conn = Nothing
   
    Unload Form2
   
End Sub

      上面介绍了在VB中使用水晶报表进行报表开发的一种方法，该方法简单易用，适合初学者上手。